AVERAGEIFS

TLDR สรุปสั้นๆ

AVERAGEIFS คำนวณค่าเฉลี่ยของกลุ่มตัวเลขตามเงื่อนไข (ใช้หลายเงื่อนไขพร้อมกันได้)

คำอธิบาย

ฟังก์ชัน AVERAGEIFS ใน Excel ใช้ในการคำนวณค่าเฉลี่ยของกลุ่มตัวเลข โดยสามารถพิจารณาหลายเงื่อนไขพร้อมกันได้ เช่น การคำนวณยอดขายเฉลี่ยของรายการขายที่ขายด้วยเงินสด ในสินค้าประเภทอาหาร

มีครั้งแรกในเวอร์ชันไหน

2007

รูปแบบคำสั่ง (Syntax)

AVERAGEIFS(average_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

Arguments

• average_range (Required – range)
  ช่วงเซลล์ที่จะคำนวณค่าเฉลี่ย เช่น กลุ่มตัวเลขที่ต้องหาค่าเฉลี่ย
• criteria_range1 (Required – range)
  ช่วงเซลล์ที่ต้องการใช้ในการพิจารณาตามเงื่อนไขที่กำหนดแรก เช่น คอลัมน์ที่เก็บค่าเงื่อนไข
• criteria1 (Required – criteria)
  เงื่อนไขสำหรับการพิจารณาเชลล์ใน criteria_range1 เช่น ‘>10’ หรือ ‘Apple’
• criteria_range2 (Optional – range)
  ช่วงเซลล์ที่สองสำหรับพิจารณาตามเงื่อนไขที่กำหนดเพิ่มเติม (ถ้ามี)
• criteria2 (Optional – criteria)
  เงื่อนไขเพิ่มเติม ถ้ามี เช่น ‘<20’ หรือ ‘Banana’

ตัวอย่างการใช้งาน (Examples)

• Formula:

  =AVERAGEIFS(G3:G8,D3:D8,"book")

  Description: หาค่าเฉลี่ยใน Range G3:G8 โดยสินค้าใน Range D3:D8 มีค่าเป็นคำว่า book ซึ่งตรง criteria1 จะใส่ว่า “book” หรือ “=book” ก็ได้นะ และไม่สนใจพิมพ์เล็กพิมพ์ใหญ่ด้วย
  Result: 950 (เกิดจาก 1100 และ 800)
  
• Formula:

  =AVERAGEIFS(TxData[SalesAmt], TxData[Product Type], "Book")

  Description: หาค่าเฉลี่ยของยอดขาย (SalesAmt) ต่อ Transaction ของสินค้าประเภท “Book” ในตาราง TxData
  Result:เกิด 950 (เกิดจาก 1100 และ 800)
  
• Formula:

  =AVERAGEIFS(TxData[SalesAmt], TxData[Product Type], "*oo*")

  Description: หาค่าเฉลี่ยของยอดขาย (SalesAmt) ในตาราง TxData ที่คอลัมน์ Product Type ที่มีคำว่า oo อยู่ในชื่อสินค้า
  Result: 966.67 (เกิดจาก 1,100 800 1,000)
  
• Formula:

  =AVERAGEIFS(TxData[SalesAmt], TxData[SalesRep], "Ra", TxData[Product Type], "Book")

  Description: หาค่าเฉลี่ยของยอดขาย (SalesAmt) ของสินค้าประเภท “Book” ที่ขายโดยพนักงาน Ra จากตาราง TxData
  Result: 1,100
  
• Formula:

  =AVERAGEIFS(TxData[SalesAmt], TxData[SalesRep], "Ple", TxData[SalesAmt], ">2000")

  Description: หาค่าเฉลี่ยของยอดขาย (SalesAmt) ทั้งหมดของพนักงานขาย Ple ที่มียอดขายเกิน 2000 จากตาราง TxData
  Result:0 (ไม่มีรายการไหนเลยที่ Ple ขายเกิน 2,000)
  
• Formula:

  =AVERAGEIFS(TxData[SalesAmt], TxData[Qty], ">=6", TxData[Qty], "<=9")

  Description: หาค่าเฉลี่ยของยอดขาย (SalesAmt) ทั้งหมดของรายการที่จำนวนสินค้า (Qty) อยู่ระหว่าง 6 ถึง 9 จากตาราง TxData
  Result: 1,100 (เกิดจาก 800 1,500 1,000)
  
• Formula:

  =AVERAGEIFS(TxData[SalesAmt], TxData[Date], ">="&DATE(2025,2,15), TxData[Date], "<="&DATE(2025,3,15))

  Description: หาค่าเฉลี่ยของยอดขาย (SalesAmt) ทั้งหมดในช่วงวันที่ตั้งแต่ 15 กุมภาพันธ์ 2025 ถึง 15 มีนาคม 2025 จากตาราง TxData
  Result: 1,250 (เกิดจาก 1,500 และ 1,000)
  

Tips & Tricks

ลองใช้ wildcard เช่น ‘*’ เพื่อค้นหาตัวอักษรที่ตามหลังอย่างไม่จำกัด เช่น ‘A*’ นอกจากนี้ ลองใช้ตัวย่อ เช่น ‘<>Incomplete’ เพื่อเลือกเฉพาะไม่มีข้อความ ‘Incomplete’ ซึ่งสามารถช่วยคัดกรองข้อมูลได้อย่างมีประสิทธิภาพ!

ข้อควรระวัง (Cautions)

ระวังการใส่เงื่อนไขผิดจะทำให้ผลลัพธ์ออกมาไม่ถูกต้อง ถ้ามีเซลล์ว่างใน average_range อาจเกิด #DIV/0! และระวังการใช้เซลล์ที่มีขนาดไม่เท่ากันกับ average_range ด้วย!

ฟังก์ชันที่เกี่ยวข้อง

• AVERAGEIF
• SUMIFS
• COUNTIFS

References

• Microsoft Official Documentation
• W3Schools AVERAGEIFS Guide
• Indeed AVERAGEIFS Tutorial

ขอบคุณที่เข้ามาอ่านนะครับ ❤️