SUMIFS

TLDR สรุปสั้นๆ

SUMIF รวมค่าตัวเลขที่ตรงกับเงื่อนไข (รองรับได้หลายเงื่อนไข)

คำอธิบาย

ฟังก์ชัน SUMIFS นั้นใช้ในการหาผลรวมตามเงื่อนไขหลาย ๆ เงื่อนไขพร้อมกันได้ เช่น รวมยอดขายเฉพาะสินค้าที่เป็น “Apple” ในเดือนมกราคม แบบนี้ทำได้สบายๆ

มีครั้งแรกในเวอร์ชันไหน

2007

รูปแบบคำสั่ง (Syntax)

SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

Arguments

• sum_range (Required – range)
  ช่วงเซลล์ที่ต้องการบวกค่าตามเงื่อนไขที่กำหนด
• criteria_range1 (Required – range)
  ช่วงเซลล์ที่ใช้ในการทดสอบเงื่อนไขแรก
• criteria1 (Required – criteria)
  เงื่อนไขที่กำหนดสำหรับ criteria_range1 เช่น ใส่ “Apples” หรือ “>32”
• criteria_range2, criteria2, … (Optional – optional_range_criteria_pairs)
  เพิ่มเติมช่วงเซลล์และเงื่อนไขที่เกี่ยวข้อง สามารถระบุได้ถึง 127 ชุดคู่ของช่วงเซลล์/เงื่อนไข

ตัวอย่างการใช้งาน (Examples)

• Formula:

  =SUMIFS(G3:G8,D3:D8,"book")

  Description: รวมยอดขายใน Range G3:G8 โดยสินค้าใน Range D3:D8 มีค่าเป็นคำว่า book ซึ่งตรง criteria1 จะใส่ว่า “book” หรือ “=book” ก็ได้นะ และไม่สนใจพิมพ์เล็กพิมพ์ใหญ่ด้วย
  Result: 1,900 (เกิดจาก 1,100 + 800)
  
• Formula:

  =SUMIFS(TxData[SalesAmt], TxData[Product Type], "Book")

  Description: คำนวณยอดขาย (SalesAmt) ทั้งหมดของสินค้าประเภท “Book” ในตาราง TxData
  Result: 1,900 (เกิดจาก 1,100 + 800)
  
• Formula:

  =SUMIFS(TxData[SalesAmt], TxData[Product Type], "*oo*")

  Description: คำนวณยอดขาย (SalesAmt) ในตาราง TxData ที่คอลัมน์ Product Type ที่มีคำว่า oo อยู่ในชื่อสินค้า
  Result: 2,900 (เกิดจาก 1,100 + 800 + 1,000)
  
• Formula:

  =SUMIFS(TxData[SalesAmt], TxData[SalesRep], "Ra", TxData[Product Type], "Book")

  Description: คำนวณยอดขาย (SalesAmt) ของสินค้าประเภท “Book” ที่ขายโดยพนักงาน Ra จากตาราง TxData
  Result: 1,100
  
• Formula:

  =SUMIFS(TxData[SalesAmt], TxData[SalesRep], "Ple", TxData[SalesAmt], ">2000")

  Description: คำนวณยอดขาย (SalesAmt) ทั้งหมดของพนักงานขาย Ple ที่มียอดขายเกิน 2000 จากตาราง TxData
  Result: 0 (ไม่มีรายการไหนเลยที่ Ple ขายเกิน 2,000)
  
• Formula:

  =SUMIFS(TxData[SalesAmt], TxData[Qty], ">=6", TxData[Qty], "<=9")

  Description: คำนวณยอดขาย (SalesAmt) ทั้งหมดของรายการที่จำนวนสินค้า (Qty) อยู่ระหว่าง 6 ถึง 9 จากตาราง TxData
  Result: 3,300 (เกิดจาก 800+1,500+1,000)
  
• Formula:

  =SUMIFS(TxData[SalesAmt], TxData[Date], ">="&DATE(2025,2,15), TxData[Date], "<="&DATE(2025,3,15))

  Description: คำนวณยอดขาย (SalesAmt) ทั้งหมดในช่วงวันที่ตั้งแต่ 15 กุมภาพันธ์ 2025 ถึง 15 มีนาคม 2025 จากตาราง TxData
  Result: 2,500 (เกิดจาก 1,500+1,000)
  

Tips & Tricks

ใช้การอ้างอิงเข้าไปใน Table หรือ Named Ranges เพื่อให้อ่านสูตรง่ายขึ้น ไม่ได้ไปคอยมองว่าอะไรคือคอลัมน์ A, B, C เหมือนการอ้างอิงเข้าไปใน Range ปกติ

สามารถใช้สัญลักษณ์ wildcard อย่าง ? และ * เพื่อการค้นหาเฉพาะที่ต้องการ เช่น

• ต้องการนับคำที่มีอักษร 7 ตัวลงท้ายด้วย “es” ใช้ “?????es”
• ต้องการคำอะไรก็ได้ที่ลงท้ายด้วย es ก็ใช้ว่า “*es”
• ต้องการคำอะไรก็ได้ที่มีคำว่า es อยู่ ใช้ “*es*”

ข้อควรระวัง (Cautions)

• อย่าลืมว่า ช่วงที่ใช้ใน SUMIFS ต้องมีขนาดเท่ากันทั้งแถวและคอลัมน์ ไม่เช่นนั้นจะได้ Error #VALUE!
• ตัวเงื่อนไข ไม่ควรใส่วันที่เป็นข้อความ เช่น “<=28/02/2025” เพราะการตีความจะขึ้นกับ Region ใน Control Panel ซึ่งจะอันตรายเวลาส่งข้อมูลให้คนอื่น ดังนั้นเราควรใส่ว่า “<=”&DATE(2025,2,28) จะปลอดภัยกว่า

ฟังก์ชันที่เกี่ยวข้อง

• SUM
• SUMIF
• IF
• COUNTIFS
• AVERAGEIFS
• FILTER

References

• Official Microsoft Documentation
• Career Principles on SUMIFS Function
• AbleBits Guide on Using SUMIFS
• Simplilearn Excel SUMIFS Tutorial

ขอบคุณที่เข้ามาอ่านนะครับ ❤️